awk 命令

awk [选项] '程序' file ...

num=123
awk -v n=$num 'BEGIN {print n}'

if (conditional)
  then-body-statement
else if (conditional)
  else-if-then-body-statement
else
  else-body-statement

initialization-statement
while (conditional) {
  body-statement
  increment-statement
  break
  continue
}

for (initialization; condition; increment)
  body-statement
  break
  continue

for (variable in array)
  body-statement
  break
  continue

switch (expression) {
case value or regular_expression:
  case-body-statement
  break
default:
  default-body-statement
  break
}

next

exit [return_code]

nextfile

cat > sales.txt << EOF
sales,fruit,color,qty,amount
john,apple,red,1,100
john,banana,yellow,2,200
john,kiwi,green,3,300
kevin,lemon,yellow,1,100
marry,banana,yellow,2,200
marry,apple,green,3,300
EOF

awk -F, '
{
  if (NR < 2) next
  fruitAmount[$2] += $5
  salesAmount[$1] += $5
}
END {
  print "---------- Fruit amount"
  for (fruit in fruitAmount) print fruit, fruitAmount[fruit]

  print "---------- Sales amount"
  for (sales in salesAmount) print sales, salesAmount[sales]
}
' sales.txt

---------- Fruit amount
apple 400
banana 400
lemon 100
kiwi 300
---------- Sales amount
kevin 100
marry 500
john 600

awk -F, '
{
  if (NR < 2) next
  fruitQty[$2,$3] += $4
  fruitAmount[$2,$3] += $5
}
END {
  PROCINFO["sorted_in"] = "@ind_str_asc"
  for (combKey in fruitQty) {
    split(combKey, sepKey, SUBSEP)
    print sepKey[1], sepKey[2], fruitQty[sepKey[1], sepKey[2]], fruitAmount[sepKey[1], sepKey[2]]
  }
}
' sales.txt

apple green 3 300
apple red 1 100
banana yellow 4 400
kiwi green 3 300
lemon yellow 1 100

awk -F, '
{
  if (NR < 2) next
  fruitQty[$2,$3] += $4
  fruitAmount[$2,$3] += $5
}
END {
  asorti(fruitQty, sortKey)
  for (i=1; i in sortKey; i++) {
    split(sortKey[i], sepKey, SUBSEP)
    print sepKey[1], sepKey[2], fruitQty[sepKey[1], sepKey[2]], fruitAmount[sepKey[1], sepKey[2]]
  }
}
' sales.txt

awk -F, '
{
  if (NR < 2) next
  fruitSales[$2][$3]["qty"] += $4
  fruitSales[$2][$3]["amt"] += $5
}
END {
  PROCINFO["sorted_in"] = "@ind_str_asc"
  for (fruit in fruitSales) {
    subqty = 0; subamt = 0;
    for (color in fruitSales[fruit]) {
      qty = fruitSales[fruit][color]["qty"]
      amt = fruitSales[fruit][color]["amt"]
      print fruit, color, qty, amt
      subqty += qty; subamt += amt;
    }
    print "--------------------"
    print fruit, "subtotal", subqty, subamt
    print ""
  }
}
' sales.txt

apple green 3 300
apple red 1 100
--------------------
apple subtotal 4 400

banana yellow 4 400
--------------------
banana subtotal 4 400

kiwi green 3 300
--------------------
kiwi subtotal 3 300

lemon yellow 1 100
--------------------
lemon subtotal 1 100

(
cat << EOF
fruit,color-list
apple,green,red
lemon,green,yellow
banana,yellow
kiwi,green,gold
grape,black,red,purple
EOF
) |
awk -F, '
{
  if (NR < 2) next
  for(i=2; i<=NF; i++)
    array[$i][$1]
}
END {
  PROCINFO["sorted_in"] = "@ind_str_asc"
  for (color in array) {
    print color, length(array[color])

    for (fruit in array[color]) {
      print "\t" fruit
    }
  }
}
'

black 1
        grape
gold 1
        kiwi
green 3
        apple
        kiwi
        lemon
purple 1
        grape
red 2
        apple
        grape
yellow 2
        banana
        lemon